Teclado Matricial 4x3

// Prueba del teclado matricial de plástico: el orden de sus pines cambia
// según el fabricante, así que este código descubre qué 2 pines une cada tecla.
const byte TOTAL = 9;
const byte PINES[TOTAL] = {2, 3, 4, 5, 6, 7, 8, 9, 10};  // pines 1 a 9 del teclado

void setup() {
  Serial.begin(9600);
  for (byte i = 0; i < TOTAL; i++) pinMode(PINES[i], INPUT_PULLUP);
  Serial.println("Presiona las teclas de una en una...");
}

void loop() {
  for (byte a = 0; a < TOTAL; a++) {
    pinMode(PINES[a], OUTPUT);  // pone un pin en 0 V...
    digitalWrite(PINES[a], LOW);
    for (byte b = a + 1; b < TOTAL; b++) {
      if (digitalRead(PINES[b]) == LOW) {  // ...y busca qué otro pin baja con él
        Serial.print("La tecla une el pin ");
        Serial.print(a + 1);
        Serial.print(" con el pin ");
        Serial.println(b + 1);
        while (digitalRead(PINES[b]) == LOW) {}  // espera a que la suelten
        delay(50);                                 // evita rebotes
      }
    }
    pinMode(PINES[a], INPUT_PULLUP);
  }
}